Problema 4.01

Estudiar la respuesta de un proceso de función de transferencia:

\[G (s) = K_p \frac{\tau s + 1}{\tau_p s + 1}\]

con las siguientes entradas:

1. función escalón unidad.

2. entrada sinusoidal. Estudiar especialmente el comportamiento del sistema para tiempos largos (es decir, para \(t \to \infty\))

---

Solución

a) La respuesta de este proceso para una entrada en escalón unidad será: $\(y (s) = G (s) \frac{1}{s} = K_p \frac{\tau s + 1}{\tau_p s + 1} \frac{1}{s}\)$ Para obtener la respuesta en tiempo real hay que realizar la transformada inversa de Laplace:

using SymPy, Plots

t, Kp, τ, Tp = symbols("t K_p tau tau_p", real=true)
s = symbols("s")

G = Kp*(τ*s+1)/(Tp*s+1)
f = 1/s

y = G*f

y_t = sympy.inverse_laplace_transform(y, s, t)
y_t = expand(y_t)
y_t = collect(y_t, Kp)
y_t = collect(y_t, exp(-t/Tp))

\[\begin{equation*}K_{p} \left(\left(\frac{\tau \theta\left(t\right)}{\tau_{p}} - \theta\left(t\right)\right) e^{- \frac{t}{\tau_{p}}} + \theta\left(t\right)\right)\end{equation*}\]

Es decir, la ecuación anterior se obtiene:

\[y (t) = K_p \left[ 1 - \left( 1 - \frac{\tau}{\tau_p} \right) e^{- \frac{t}{\tau_p}} \right]\]

Se obtiene una ecuación muy similar a la ec. (4.4). Evidentemente el sentido físico e influencia sobre la respuesta del sistema de la ganancia del proceso (\(K_p\)) serán los mismos que para un sistema de primer orden. La influencia de la constante de tiempo del proceso (\(\tau_p\)) también será muy parecida.

La única diferencia es el término \(\tau / \tau_p\). Para ver el significado físico de la constante de tiempo \(\tau\) se puede representar la respuesta para diferentes valores \((K_p = \tau_p = 1)\):

taus = [0, .25, .5, 1, 2, 3]

p = plot()

for tau in taus
    plot!(y_t(Kp=>1, Tp=>1, τ=>tau), 0, 5, label=tau, lw=2)
end

p

Se observa como \(\tau\), para valores inferiores a la unidad, actua como un adelanto, avanza la respuesta del proceso de primer orden en un valor igual a \(\tau\).

En el caso de una entrada sinusoidal (\(\sin(\omega t)\)), la ransformada de Laplace de la respuesta es:

\[y (s) = \frac{K_p (\tau s + 1)}{\tau_p s + 1} \frac{\omega}{s^2 + \omega^2}\]

Recurriendo de nuevo a Sympy para realizar la transformada inversa de Laplace:

w = symbols("omega", real=true)

f_t = sin(w*t)

f = sympy.laplace_transform(f_t, t, s, noconds=true)

y = G*f

y_t = sympy.inverse_laplace_transform(y, s, t)

\[\begin{equation*}\frac{K_{p} \left(\omega^{2} \tau_{p}^{2} + 1\right) \left(\omega^{2} \tau \tau_{p} e^{\frac{t}{\tau_{p}}} \sin{\left(\omega t \right)} + \omega \tau e^{\frac{t}{\tau_{p}}} \cos{\left(\omega t \right)} - \omega \tau - \omega \tau_{p} e^{\frac{t}{\tau_{p}}} \cos{\left(\omega t \right)} + \omega \tau_{p} + e^{\frac{t}{\tau_{p}}} \sin{\left(\omega t \right)}\right) e^{- \frac{t}{\tau_{p}}} \theta\left(t\right)}{\left(\omega \tau_{p} - i\right)^{2} \left(\omega \tau_{p} + i\right)^{2}}\end{equation*}\]

y_t = cancel(y_t)
y_t = collect(y_t, exp(t/Tp))
y_t = collect(y_t, sin(w*t))
y_t = collect(y_t, cos(w*t))

\[\begin{equation*}\frac{\left(- K_{p} \omega \tau \theta\left(t\right) + K_{p} \omega \tau_{p} \theta\left(t\right) + \left(\left(K_{p} \omega \tau \theta\left(t\right) - K_{p} \omega \tau_{p} \theta\left(t\right)\right) \cos{\left(\omega t \right)} + \left(K_{p} \omega^{2} \tau \tau_{p} \theta\left(t\right) + K_{p} \theta\left(t\right)\right) \sin{\left(\omega t \right)}\right) e^{\frac{t}{\tau_{p}}}\right) e^{- \frac{t}{\tau_{p}}}}{\omega^{2} \tau_{p}^{2} + 1}\end{equation*}\]

Es decir:

\[y (t) = \frac{(K_p \omega \tau_p^2 - K_p \omega \tau \tau_p) \mathrm{e}^{- \frac{t}{\tau_p}}}{\tau_p (\omega^2 \tau^2_p + 1)} + \frac{K_p \omega^3 \tau \tau_p + K_p \omega}{\omega (\omega^2 \tau^2_p + 1)} \sin (\omega t) - \frac{K_p \omega \tau_p - K_p \omega \tau}{\omega^2 \tau^2_p + 1} \cos (\omega t)\]

Considerando la propiedad trigonométrica:

\[x \sin \alpha + y \cos \alpha = z \sin (\alpha + \varphi)\]

donde \(z^2 = x^2 + y^2\) y \(\tan \varphi = \frac{y}{x}\), se obtiene:

\[y (t) = \frac{(K_p \omega \tau_p^2 - K_p \omega \tau \tau_p) e^{- \frac{t}\tau_p}}{\tau_p (\omega^2 \tau^2_p + 1)} + \sqrt{\frac{K_p^2 \omega^2 \tau^2 + K^2_p}{\omega^2 \tau^2_p + 1}} \sin (\omega t + \varphi)\]

donde

\(\varphi = \mathrm{atan} \left( \frac{\omega^2 (K_p \omega \tau_p - K_p \omega \tau)^2}{(K_p \omega^3 \tau \tau_p + K_p \omega)^2} \right) = \mathrm{atan} \left( \frac{\omega^2 (\tau_p - \tau)^2}{(\omega^2 \tau \tau_p + 1)^2} \right)\).

Se obtiene una respuesta con una parte transitoria, que rápidamente se anula al aumentar el tiempo:

\[\mathrm{Transitorio} = \lim_{t \to 0} \frac{(K_p \omega \tau_p^2 - K_p \omega \tau \tau_p) e^{- \frac{t}{\tau_p}}}{\tau_p (\omega^2 \tau^2_p + 1)} = 0\]

La parte estacionaria de la respuesta es:

\[y (t) = K_p \sqrt{\frac{\omega^2 \tau^2 + 1}{\omega^2 \tau^2_p + 1}} \sin (\omega t + \varphi)\]

Si se compara la respuesta estacionaria respecto a la entrada se comprueba que tiene la misma frecuencia angular \(\omega\) y que tiene un desfase \(\varphi\), lo que significa que está retrasada. Este desfase depende de la frecuencia angular. La amplitud de la respuesta también depende de la frecuencia angular de la entrada.

Nuevamente la respuesta obtenida es muy similar a la de un proceso de primer orden. Por tanto, la influencia de la ganancia y constante de tiempo del proceso serán similares.

La constante de tiempo \(\tau\) nuevamente actua como un adelanto, compensando en cierta medida el efecto de la constante de tiempo del proceso. Al aumentar su valor disminuye el desfase y la amplitud disminuye en menor medida que para un proceso de primer orden.